float ramas;
void setup()
{
  smooth();
  size(700,500);
  background(255);
  // Vamos a escoger un ángulo de 0 a 90 grados y convertir
  // Nuestra variable ramas a Radianes
  ramas= radians(30);
  // Inicia el árbol desde la parte inferior de la pantalla
  translate(width /4,height);
  strokeWeight(40);
  // Dibuja una línea de 50 píxeles
  line(160,160,160,-50);
  strokeWeight(30);
  // Dibuja una línea de 100 píxeles
  line(160,160,160,-100);
  // Mueve la funcion arbol al final de la linea
  translate(160,-100);
  // Inicia la funcion arbol
  arbol(150,20);
}
 
void arbol(float h,float s)
{
  // Cada Rama creada sera mas delgada que la anterior en cuanto a largo y grueso
  h *=0.7;
  s *=0.6;
 
  // Todas las funciones deben tener una condición de salida!!
  // Aquí, la nuestra es cuando la longitud de la rama es de 1 píxeles o menos
 
  if(h > 1)
  {
 
    pushMatrix(); // Guardar el estado actual de transformación (es decir, donde estamos ahora)
    strokeWeight(s*0.5); // Se adelgaza la linea a la mitad
    rotate(-ramas); // Rotar por ramas
    line(0,0,0,-h); // Dibuja la rama
    translate(0,-h); // Ir al final de la rama
    arbol(h,s); // Ok, ahora se llaman arbol para dibujar dos nuevas ramas!
    popMatrix(); // Cada vez que volvamos aquí, se restaura el estado anterior de la matriz
 
    // Repetir lo mismo, sólo se ramificara hacia la izquierda esta vez y eh cambiado algunos valores para que el lado izquierdo no sea igual al derecho!
    pushMatrix();
    strokeWeight(s*0.6);
    rotate(ramas);
    line(0,0,0,-h-10);
    translate(0,-h-10);
    arbol(h,s);
    popMatrix();
 
  }
}